home *** CD-ROM | disk | FTP | other *** search
/ Shareware Games Galore! / Shareware Games Galore!.iso / arcade / gameser5 / king.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  6.0 KB  |  236 lines
  1. 1  CLS:KEY OFF
  2. 10  OUT 2,26
  3. 30  N5=8:N4=8
  4. 100  INPUT "WHAT IS YOUR NAME";A$
  5. 105  B$=""
  6. 110  IF LEFT$(A$,4)="KING" THEN 370
  7. 120  IF LEFT$(A$,4)="QUEE" THEN 370
  8. 130  PRINT"ARE YOU KING OR QUEEN ";A$
  9. 140  INPUT B$
  10. 370  PRINT"GREETINGS ";B$;" ";A$
  11. 380  PRINT"YOUR GOAL: TO COMPLETE YOUR ";N4;" YEAR TERM."
  12. 390  PRINT"GOOD LUCK<UNK! {0007}><UNK! {0007}>"
  13. 400  M=INT(70000+(RND(1)*1000)-(RND(2)*1000))
  14. 410  P=INT(500 +(RND(3)*10)-(RND(4)*10))
  15. 420  L=2000
  16. 430  W=0:X2=0:E0=0:X1=0:E1=0:S9=0:S0=0:M5=0:S1=0
  17. 440  D1=INT(P/3)
  18. 450  L1=INT((RND(0)*5)+10)
  19. 460  L0=INT(RND(0)*10+95)
  20. 470  GOSUB 2220
  21. 471  PRINT B$;" ";A$;" ";
  22. 472  PRINT"THIS IS THE START OF YEAR ";(N4-N5)+1;"OF YOUR "; N4;"YEAR REIGN."
  23. 480  PRINT"YOU HAVE ";M;" RALLODS, ";
  24. 490  PRINT P;" COUNTRYMEN,";
  25. 500  IF W=0 THEN 520
  26. 510  PRINTW;" FOREIGN WORKERS,";
  27. 520  PRINT" AND";L;" SQ. MILES OF LAND."
  28. 530  PRINT"THIS YEAR INDUSTRY WILL BUY LAND FOR";L0;" RALLODS/SQ. MILE"
  29. 540  PRINT"LAND CURRENTLY COSTS";L1;" RALLODS/SQ. MILE TO PLANT"
  30. 550  IF S1=0 THEN 570
  31. 560  PRINT"POLLUTION LEVEL IS ";S1;" UNITS."
  32. 570  GOSUB 2220
  33. 580  INPUT"HOW MANY SQ. MILES TO SELL TO INDUSTRY ";L2
  34. 600  IF L2<0 THEN 580
  35. 610  IF L2<(L-1000) THEN 680
  36. 620  PRINT"  THINK AGAIN. YOU'VE ONLY";L-1000;" SQ. MILES OF FARM LAND"
  37. 630  IF X<>1 THEN 580
  38. 640  PRINT"(FOREIGN INDUSTRY NOT INTERESTED IN FOREST LAND BECAUSE"
  39. 650  PRINT"OF GREATER DEVELOPMENT COST)"
  40. 660  X1=1
  41. 670  GOTO 580
  42. 680  M=INT(M+L2*L0)
  43. 690  L=INT(L-L2)
  44. 700  X9=INT(44*(2000-L))
  45. 710  M2=0
  46. 720  M3=0
  47. 730  M4=0
  48. 740  INPUT"HOW MANY RALLODS TO DISTRIBUTE TO YOUR COUNTRYMEN ";M1
  49. 770  IF M1<0 THEN 740
  50. 780  IF M1<=M THEN 810
  51. 790  GOSUB 2250
  52. 800  GOTO 740
  53. 810  M=INT(M-M1)
  54. 820  IF M=0 THEN 1170
  55. 830  INPUT"HOW MANY SQ. MILES TO PLANT ";L3
  56. 850  IF L3<0 THEN 830
  57. 860  IF L3<=P*2 THEN 890
  58. 870  PRINT"EACH COUNTRYMAN CAN ONLY PLANT 2 SQ. MILES":GOTO 950
  59. 890  IF L3<=L-1000 THEN 920
  60. 900  PRINT"ONLY GOT";L-1000;" SQ. MILES OF FARM LAND."
  61. 910  GOTO 950
  62. 920  M4=INT(L3*L1)
  63. 930  IF M4<=M THEN 990
  64. 940  GOSUB 2250
  65. 950  PRINT"YOU CAN AFFORD";INT(M/L1);
  66. 960  PRINT" AND HAVE LABOR FOR";P*2;
  67. 970  PRINT" AND HAVE";L-1000;" SQ. MILES":GOTO 830
  68. 990  M=INT(M-M4)
  69. 1000  IF M=0 THEN 1170
  70. 1010  INPUT"HOW MUCH TO SPEND FOR EDUCATION ";M2
  71. 1030  IF M2<0 THEN 1010
  72. 1040  IF M2<M THEN 1070
  73. 1050  GOSUB 2250
  74. 1060  GOTO 1010
  75. 1070  M=INT(M-M2)
  76. 1080  IF M=0 THEN 1170
  77. 1090  IF L=2000 THEN 1170
  78. 1100  INPUT"HOW MUCH TO SPEND TO COMBAT POLLUTION ";M3
  79. 1120  IF M3<0 THEN 1100
  80. 1130  IF M3<=M THEN 1160
  81. 1140  GOSUB 2250
  82. 1150  GOTO 1100
  83. 1160  M=INT(M-M3)
  84. 1170  GOSUB 2220
  85. 1180  D0=0
  86. 1190  E2=M2/P
  87. 1200  D2=INT(P-M1/100)
  88. 1210  IF D2<=0 THEN 1240
  89. 1220  D0=D2
  90. 1230  PRINT D2;" COUNTRYMEN DIED OF STARVATION."
  91. 1240  D3=INT((S1/100000)*(0.1+0.4*RND(1))*P)
  92. 1250  IF D3<=0 THEN 1280
  93. 1260  PRINT D3;" COUNTRYMEN DIED OF EXCESS POLLUTION."
  94. 1270  D0=D0+D3
  95. 1280  IF D0<=0THEN 1400
  96. 1290  F=D0*9
  97. 1300  PRINT"YOU WERE FORCE TO SPEND";F;" RALLODS FOR FUNERAL EXPENSES"
  98. 1310  M=INT(M-F)
  99. 1320  IF M<=0 THEN 1400
  100. 1330  PRINT"INSUFFICIENT RESOURCES FORCED SALE OF LAND."
  101. 1340  T0=-INT((M-L0+1)/L0)
  102. 1350  L=L-T0
  103. 1360  IF L>=1000 THEN 1390
  104. 1370  PRINT"NOT ENOUGH LAND TO SELL"
  105. 1380  GOTO 2270
  106. 1390  M=M+T0*L0
  107. 1400  IF D0>200 THEN 2300
  108. 1410  P=P-D0
  109. 1420  D1=D1-D0
  110. 1430  IF D1<0 THEN 2410
  111. 1440  IF D2<=2 THEN 1460
  112. 1450  IF M>500 THEN 2520
  113. 1460  IF L2=0 THEN 1520
  114. 1470  T0=INT(L2+L2*RND(2)*2)
  115. 1480  IF W=0 THEN 1500
  116. 1490  T0=INT(T0+0.1*W)
  117. 1500  PRINT T0;" WORKERS CAME TO THE ISLAND AND"
  118. 1510  W=W+T0
  119. 1520  T0=INT(((500-P)/10-D3/3-D2/5)*0.75*(1+RND(1)))
  120. 1530  PRINT ABS(T0);" COUNTRYMEN ";
  121. 1540  IF T0<0THEN 1570
  122. 1550  PRINT"CAME TO";
  123. 1560  GOTO 1580
  124. 1570  PRINT"LEFT";
  125. 1580  PRINT" THE ISLAND."
  126. 1590  P=P+T0
  127. 1600  IF P<W THEN 2480
  128. 1610  T0=0
  129. 1620  IF L=2000 THEN 1680
  130. 1630  T0=INT((S1/100000)*L3)
  131. 1640  IF T0<=L3 THEN 1660
  132. 1650  T0=L3
  133. 1660  IF T0=0 THEN 1680
  134. 1670  PRINT"OF";L3;" SQ. MILES PLANTED, ";
  135. 1680  PRINT"YOU HARVESTED";L3-T0;" SQ. MILES OF CROPS."
  136. 1690  IF T0=0 THEN 1760
  137. 1700  IF X2>=2 THEN 1760
  138. 1710  PRINT"  (DUE TO ";
  139. 1720  IF X2=0 THEN 1740
  140. 1730  PRINT"INCREASED ";
  141. 1740  PRINT"POLLUTION LEVEL)"
  142. 1750  X2=X2+1
  143. 1760  T1=INT((39+RND(1)*20)*(1+0.25*(E0+E1)/20))
  144. 1770  PRINT"  MAKING";INT(T1*(L3-T0));" RALLODS."
  145. 1780  M=M+INT(T1*(L3-T0))
  146. 1790  E0=E1
  147. 1800  IF E2<=10 THEN 1820
  148. 1810  E2=10
  149. 1820  E1=E2
  150. 1830  T0=2000-L
  151. 1840  IF T0<2 THEN 2100
  152. 1850  IF T0<=26 THEN 1870
  153. 1860  T0=26
  154. 1870  T0=INT(T0*500*(0.52+0.5*RND(6)))
  155. 1880  T1=S1/100000
  156. 1890  IF T1<=1 THEN 1910
  157. 1900  T1=1
  158. 1910  T1=T1*T0
  159. 1920  PRINT"YOU MADE";INT(T0-T1);" RALLODS FROM TOURIST TRADE"
  160. 1930  M=M+INT(T0-T1)
  161. 1940  IF INT(T0-T1)<=M5 THEN 2080
  162. 1950  IF S1<=S9 THEN 2080
  163. 1960  PRINT"  DECREASE BECAUSE ";
  164. 1970  T2=RND(1)*10
  165. 1980  ON (T2/2)+1 GOTO 1990,2010,2030,2050,2070,2070
  166. 1990  PRINT"FISH POPULATIN HAS DWINDLED DUE TO WATER POLLUTION"
  167. 2000  GOTO 2080
  168. 2010  PRINT"AIR POLLUTION IS KILLING GAME BIRD POPULATION"
  169. 2020  GOTO 2080
  170. 2030  PRINT"MINERAL BATHS ARE BEING RUINED BY WATER POLLUTION"
  171. 2040  GOTO 2080
  172. 2050  PRINT"UNPLEASANT SMOG IS DISCOURIGING SUN BATHERS"
  173. 2060  GOTO 2080
  174. 2070  PRINT"HOTEL ARE LOOKING SHABBY DUE TO SMOG GRIT"
  175. 2080  M5=INT(T0-T1)
  176. 2090  S9=S1
  177. 2100  S2=(2000-L)^2-M3/0.44
  178. 2110  PRINT"YOU RECEIVED";X9;" RALLODS FROM TAXES ON INDUSTRY"
  179. 2120  IF S2>=0 THEN 2170
  180. 2130  S1=INT(S1+S2/2)
  181. 2140  IF S1>=S0 THEN 2160
  182. 2150  S1=S0
  183. 2160  GOTO 2190
  184. 2170  S1=INT(S1+S2)
  185. 2180  S0=INT(S0+S2/10)
  186. 2190  N5=N5-1
  187. 2200  IF N5>0 THEN 450
  188. 2210  GOTO 2570
  189. 2220  PRINT:PRINT:RETURN
  190. 2250  PRINT"ONLY GOT";M;" RALLODS LEFT!<UNK! {0007}><UNK! {0007}>":RETURN
  191. 2270  PRINT"YOU HAVE BEEN THROWN OUT OF OFFICE AND YOU ARE NOW"
  192. 2280  PRINT"RESIDING IN PRISON."
  193. 2290  GOTO 2615
  194. 2300  PRINT D0;" COUNTRYMEN DIED IN ONE YEAR!!!!!"
  195. 2310  PRINT"DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY"
  196. 2320  PRINT"BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU"
  197. 2330  T0=INT(RND(1)*2.01)+1
  198. 2340  ON T0 GOTO 2350,2370,2390
  199. 2350  PRINT"ALSO HAD YOUR LEFT EYE GOUGED OUT."
  200. 2360  GOTO 2615
  201. 2370  PRINT"HAVE ALSO GAINED A VERY BAD REPUTATION."
  202. 2380  GOTO 2615
  203. 2390  PRINT"HAVE ALSO BEEN DECLARED NATIONAL FINK."
  204. 2400  GOTO 2615
  205. 2410  PRINT"OVER ONE THIRD OF THE POPULATION HAS DIED SINCE YOU"
  206. 2420  PRINT"WERE ELECTED TO OFFICE.  THE PEOPLE (REMAINING)"
  207. 2430  PRINT"HATE YOUR GUTS."
  208. 2440  GOTO 2450
  209. 2450  IF RND(2)<0.25 THEN 2270
  210. 2460  PRINT"YOU HAVE BEEN ASSASINATED, AND YOUR BODY THROWN IN" 
  211. 2465  PRINT" THE BREA DUMP.  " 
  212. 2470  GOTO 2615
  213. 2480  PRINT"THE NUMBER OF FOREIGN WORKERS HAS EXCEEDED THE NUMBER"
  214. 2490  PRINT"OF COUNTRYMEN. AS A MAJORITY THEY HAVE REVOLTED AND"
  215. 2500  PRINT"TAKEN OVER THE COUNTRY."
  216. 2510  GOTO 2450
  217. 2520  PRINT"MONEY WAS LEFT OVER IN THE TREASURY WHICH YOU DID NOT"
  218. 2530  PRINT"SPEND.  AS A RESULT SOME OF YOUR COUNTRYMEN DIED OF "
  219. 2540  PRINT"STARVATION.  THE PUBLIC IS ENRAGED AND YOU HAVE BEEN"
  220. 2550  PRINT"FORCED TO EITHER RESIGN OR COMMIT SUICIDE."
  221. 2560  GOTO 2615
  222. 2570  PRINT
  223. 2580  PRINT"CONGRATULATIONS ";B$;" ";A$
  224. 2585  PRINT
  225. 2590  PRINT"YOU HAVE SUCCESSFULLY COMPLETED YOUR";N4;" YEAR TERM"
  226. 2600  PRINT"OF OFFICE.  YOU HAVE DONE SUCH A GOOD JOB THAT YOU MIGHT"
  227. 2610  PRINT"WANT TO RUN FOR ELECTION AGAIN THIS TIME."
  228. 2615  PRINT:PRINT:PRINT"WOULD YOU LIKE TO TRY AGAIN ";B$;" ";A$;"?"
  229. 2620  INPUT"TYPE YES OR NO.";Q$
  230. 2625  N5=N4
  231. 2630  IF LEFT$(Q$,1)="Y" THEN 440
  232. 2640  IF LEFT$(Q$,1)="N" THEN 3000
  233. 2660  GOTO 2620
  234. 3000  PRINT:PRINT B$;" ";A$;" IS A CHICKEN!!!!!!"
  235. 3010  END
  236.